martes, 14 de marzo de 2017

GPO : Definir Internet Explorer como navegador por defecto

Hola,

Se que hay muchas formas de realizarlo. Hoy en el trabajo tenia un entorno antiguo y esta ha sido la forma que mejor se adaptaba al entorno, para definir Internet Explorer como navegador por defecto.

Como veis, las paginas web se abren con , por ejemplo Firefox.


Vamos a generar un script de inici de sesion


Estos son los detalles de la GPO


Aqui os dejo el codigo :

@echo off
setlocal enabledelayedexpansion

REM -- check XHTML support (IE 9+)
set xhtml=0
for /f %%G in ('"reg query "HKCR\IE.AssocFile.XHT" /ve 2>&1 | findstr /c:".XHT" "') do set xhtml=1

REM -- reset file extensions
set exts=HTM,HTML
if %xhtml% == 1 (set exts=%exts%,XHT,XHTML)

for %%G in (%exts%) do (
set ext=%%G
set ext=!ext:~0,3!
reg add "HKCU\Software\Classes\.%%G" /ve /t REG_SZ /d "IE.AssocFile.!ext!" /f >nul
)

set exts=%exts%,MHT,MHTML,URL
set acl=%temp%\acl_%random%%random%.txt

for %%G in (%exts%) do (
set key=HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.%%G\UserChoice
echo !key! [1 7 17]>"%acl%"
regini "%acl%" >nul
set ext=%%G
set ext=!ext:~0,3!
reg add "!key!" /v "Progid" /t REG_SZ /d "IE.AssocFile.!ext!" /f >nul
)
del "%acl%" 2>nul

REM -- reset MIME associations
for %%G in (message/rfc822,text/html) do (
set key=HKCU\Software\Microsoft\Windows\Shell\Associations\MIMEAssociations\%%G\UserChoice
reg add "!key!" /v "Progid" /t REG_SZ /d "IE.%%G" /f >nul
)

REM -- reset URL protocols
for %%A in (FTP,HTTP,HTTPS) do (
set key=HKCU\Software\Microsoft\Windows\Shell\Associations\UrlAssociations\%%A\UserChoice
reg add "!key!" /v "Progid" /t REG_SZ /d "IE.%%A" /f >nul
for %%B in (DefaultIcon,shell) do (
set key=HKCU\Software\Classes\%%A
reg delete "!key!\%%B" /f >nul 2>&1
reg copy "HKCR\IE.%%A\%%B" "!key!\%%B" /s /f >nul
reg add "!key!" /v "EditFlags" /t REG_DWORD /d 2 /f >nul
reg add "!key!" /v "URL Protocol" /t REG_SZ /d "" /f >nul
))

REM -- reset the start menu Internet link (Vista and earlier)
reg add "HKCU\Software\Clients\StartMenuInternet" /ve /t REG_SZ /d "IEXPLORE.EXE" /f

REM -- reset cached icons
if %xhtml% == 1 (
ie4uinit -cleariconcache
) else (
taskkill /im explorer.exe /f >nul
start explorer
)


exit

Despues de iniciar el equipo, vereis como Internet Explorer es el navegador por defecto.


jueves, 2 de marzo de 2017

Reinicio remoto de servidores

Hoy he tenido un problema con el servicio NETLOGON en un Windows Server. Total que he intentado reiniciar el servicio, conectandome al SERVICES.MSC desde otro servidor.
El servicio netlogon despues de pararse, no se queria volver a iniciar.
Este servidor era un DC por lo que no podia entrar en local. Tampoco me dejaba acceder a el mediante ninguna aplicacion del estilo DameWare, VCN etc...

Tocaba la solucion definitiva, el reinicio. He estado a punto de enviar a un compañero presencial , ya que el servidor no estaba en la oficina. Pero... he utilizado este comando para reiniciar en remoto.

Os lo dejo en la version Windows Server 2016, los datos son los mismos en 2008 y 2012.
En 2003 es en vez de con los "-" con las "/"

Aqui teneis el comando.

-r : Para reiniciar
-f: Fuerza el reinicio ( por si algun usuario esta conectado )
-m : Para indicarle despues el \\nombre del server
-c: Para indicar un comentario.


Aqui os dejo lo que ha salido en el servidor que queria reiniciar.


Aqui vemos con un PING el proceso del reinicio.